readparameters.l

Go to the documentation of this file.

%{ 

#include <stdlib.h> 
#include <string.h>

#include "defines.h"
#include "readparameters.tab.h"

int ReadParameterslex(void);

extern unsigned int RPNline; /*current line number (declared in the YACC module and updated here)*/

%} 
 
%s IN_COMMENT

EMPTY                           [ \t]+ 
RETURN                          \n
DIGIT                           [0-9] 
LETTER                          [a-zA-Z] 
R_NUMBER                        (({DIGIT}+(\.{DIGIT}+)?)|(\.{DIGIT}+))((E|e)[+-]?{DIGIT}+)? 
I_NUMBER                        {DIGIT}+ 
IDENTIFIER                      {LETTER}({DIGIT}|{LETTER}|"_")* 
COMMENT                         \%[^\n]*
COMMENT2                        \#[^{\n|\{}]* 
 
%%

{COMMENT}                       { }   
{COMMENT2}                      { }  

<INITIAL>{
  "/*"              BEGIN(IN_COMMENT);
}
<IN_COMMENT>{
  "*/"      BEGIN(INITIAL);
  [^*\n]+   // eat comment in chunks
  "*"       // eat the lone star
  \n        RPNline++;
}

{EMPTY}                         { } 

{RETURN}                        { RPNline++; } 

TRUE                            { return(_TRUE);}
FALSE                           { return(_FALSE);}

INF                             { return(_INF);}

EPSILON                         { return(_EPSILON);}

RHO                             { return(_RHO);}

SIGMA                           { return(_SIGMA);}
SMALL_SIGMA                     { return(_SMALL_SIGMA);}

STATE_PERIOD                    { return(_STATE_PERIOD);}

DUMMIFY                         { return(_DUMMIFY);}
ERROR_SPLIT                     { return(_ERROR_SPLIT);}
SAFE_SIMPLEX                    { return(_SAFE_SIMPLEX);}
SIMPLIFICATION_LEVEL            { return(_SIMPLIFICATION_LEVEL);}
LR2TM_Q                         { return(_LR2TM_Q);}
LR2TM_S                         { return(_LR2TM_S);}

{I_NUMBER}                      {
                                  char string_tmp[100];
                                  
                                  memcpy(string_tmp,ReadParameterstext,(unsigned int)ReadParametersleng);
                                  string_tmp[ReadParametersleng]=0;
                                  ReadParameterslval.int_number=atoi(string_tmp);
                                  return(_INTEGER); 
                                } 
 
{R_NUMBER}                      { 
                                  char string_tmp[100];
                                  
                                  memcpy(string_tmp,ReadParameterstext,(unsigned int)ReadParametersleng);
                                  string_tmp[ReadParametersleng]=0;
                                  ReadParameterslval.real_number=atof(string_tmp);
                                  
                                  return(_REAL);
                                }
 
.                               { return(ReadParameterstext[0]); }
 
%%

int ReadParameterswrap()
{
  return(1);
}